返回列表 發帖
角色

Rank: 2
1# 跳轉到 » 倒序看帖
打印
tT
發表於 2014-9-6 02:57 | 只看該作者

【RouterOS】—— Initial configuration from scratch

我在想，RouterOS在RB的settings是否预置好，就是简单修改一下就可以用，这个修改不能让你RouterOS有更加大的进展，所以自己却有一个想法就是像学Asterisk一样，从新自己去建立，一定一滴去学习，总有一天我对RouterOS认识更加深。

http://wiki.mikrotik.com/wiki/Manual:Initial_Configuration
收藏 分享

角色

Rank: 2
2#
發表於 2014-9-7 15:58 | 只看該作者
The following script will be run for each system reset configuration.
  1. :global ssid;
  2. #| Wireless Configuration:
  3. #|     mode:                ap-bridge;
  4. #|     band:                2ghz-b/g/n;
  5. #|     ht-chains:        two;
  6. #|     ht-extension:   20/40mhz-ht-above;
  7. #|
  8. #| WAN (gateway) Configuration:
  9. #|     gateway:        ether1  (renamed with extension '-gateway');
  10. #|     firewall:         enabled;
  11. #|     NAT:                enabled;
  12. #|     DHCP Client:        enabled;
  13. #|
  14. #| LAN Configuration:
  15. #|     LAN Port:        bridge-local;
  16. #|     switch group:        ether2 (master), ether3, ether4, ether5
  17. #|          (renamed with extensions '-master-local' and '-slave-local')
  18. #|     LAN IP:                192.168.88.1;
  19. #|     DHCP Server:        enabled;

  21. :global action;

  23. #-------------------------------------------------------------------------------
  24. # Apply configuration.
  25. # these commands are executed after installation or configuration reset
  26. #-------------------------------------------------------------------------------
  27. :if ($action = "apply") do={
  28. # wait for interfaces
  29. :while ([/interface ethernet find] = "") do={ :delay 1s; };

  31.                 :local count 0;
  32.                 :while ([/interface wireless find] = "") do={
  33.                         :set count ($count +1);
  34.                         :if ($count = 60) do={
  35.                                 :log warning "DefConf: Unable to find wireless interface";
  36.                                 /ip address add address=192.168.88.1/24 interface=ether1;
  37.                                 /quit
  38.                         }
  39.                         :delay 1s;
  40.                 };
  41.         /interface wireless set wlan1 mode=ap-bridge band=2ghz-b/g/n ht-txchains=0,1 ht-rxchains=0,1 \
  42.             disabled=no wireless-protocol=any distance=indoors
  43.                 :local wlanMac  [/interface wireless get wlan1 mac-address];
  44.                 :set ssid "MikroTik-$[:pick $wlanMac 9 11]$[:pick $wlanMac 12 14]$[:pick $wlanMac 15 17]"
  45.                 /interface wireless set wlan1 ssid=$ssid
  46.        /interface wireless set wlan1 channel-width=20/40mhz-ht-above ;
  47.         /interface set ether1 name="ether1-gateway";
  48.                 /ip dhcp-client add interface=ether1-gateway disabled=no comment="default configuration";
  49.         /interface {
  50.                 set ether2 name=ether2-master-local;
  51.                 set ether3 name=ether3-slave-local;
  52.                 set ether4 name=ether4-slave-local;
  53.                 set ether5 name=ether5-slave-local;
  54.         }
  55.         /interface ethernet {
  56.                 set ether3-slave-local master-port=ether2-master-local;
  57.                 set ether4-slave-local master-port=ether2-master-local;
  58.                 set ether5-slave-local master-port=ether2-master-local;
  59.         }

  61.         /interface bridge
  62.                 add name=bridge-local disabled=no auto-mac=no protocol-mode=rstp;
  63.         :local bMACIsSet 0;
  64.         :foreach k in=[/interface find] do={
  65.                 :local tmpPortName [/interface get $k name];
  66.                 :if (!($tmpPortName~"bridge"  || $tmpPortName~"ether1"|| $tmpPortName~"slave")) do={
  67.                         :if ($bMACIsSet = 0) do={
  68.                                 :if ([/interface get $k type] = "ether") do={
  69.                                         /interface bridge set "bridge-local" admin-mac=[/interface ethernet get $tmpPortName mac-address];
  70.                                         :set bMACIsSet 1;
  71.                                 }
  72.                         }
  73.                         /interface bridge port
  74.                                 add bridge=bridge-local interface=$tmpPortName;
  75.                 }
  76.         }
  77.         /ip address add address=192.168.88.1/24 interface=bridge-local comment="default configuration";
  78.                 /ip pool add name="default-dhcp" ranges=192.168.88.10-192.168.88.254;
  79.                 /ip dhcp-server
  80.                         add name=default address-pool="default-dhcp" interface=bridge-local lease-time=10m disabled=no;
  81.                 /ip dhcp-server network
  82.                         add address=192.168.88.0/24 gateway=192.168.88.1 dns-server=192.168.88.1 comment="default configuration";
  83. /ip dns {
  84.      set allow-remote-requests=yes
  85.      static add name=router address=192.168.88.1
  86. }

  88.         /ip firewall nat add chain=srcnat out-interface=ether1-gateway action=masquerade comment="default configuration"
  89.         /ip firewall {
  90.                 filter add chain=input action=accept protocol=icmp comment="default configuration"
  91.                 filter add chain=input action=accept connection-state=established comment="default configuration"
  92.                 filter add chain=input action=accept connection-state=related comment="default configuration"
  93.                 filter add chain=input action=drop in-interface=ether1-gateway comment="default configuration"
  94.               filter add chain=forward action=accept connection-state=established comment="default configuration"
  95.               filter add chain=forward action=accept connection-state=related comment="default configuration"
  96.               filter add chain=forward action=drop connection-state=invalid comment="default configuration"
  97.         }
  98.         /tool mac-server disable [find];
  99.         /tool mac-server mac-winbox disable [find];
  100.         :foreach k in=[/interface find] do={
  101.                 :local tmpName [/interface get $k name];
  102.                 :if (!($tmpName~"ether1-gateway")) do={
  103.                         /tool mac-server add interface=$tmpName disabled=no;
  104.                         /tool mac-server mac-winbox add interface=$tmpName disabled=no;
  105.                 }
  106.         }
  107.         /ip neighbor discovery set [find name="ether1-gateway"] discover=no
  108. }

  110. #-------------------------------------------------------------------------------
  111. # Revert configuration.
  112. # these commands are executed if user requests to remove default configuration
  113. #-------------------------------------------------------------------------------
  114. :if ($action = "revert") do={
  115. # remove wan port protection
  116.         /ip firewall {
  117.                 :local o [nat find comment="default configuration"]
  118.                 :if ([:len $o] != 0) do={ nat remove $o }
  119.                 :local o [filter find comment="default configuration"]
  120.                 :if ([:len $o] != 0) do={ filter remove $o }
  121.         }
  122.         /tool mac-server remove [find interface!=all]
  123.         /tool mac-server set [find] disabled=no
  124.         /tool mac-server mac-winbox remove [find interface!=all]
  125.         /tool mac-server mac-winbox set [find] disabled=no
  126. # reset wan ports;
  127.         /ip neighbor discovery set [find name="ether1-gateway"] discover=yes
  128.         /interface set "ether1-gateway" name=ether1;
  129.                 :local o [/ip dhcp-server network find comment="default configuration"]
  130.                 :if ([:len $o] != 0) do={ /ip dhcp-server network remove $o }
  131.                 :local o [/ip dhcp-server find name="default" address-pool="default-dhcp" interface="bridge-local" !disabled]
  132.                 :if ([:len $o] != 0) do={ /ip dhcp-server remove $o }
  133.                 /ip pool {
  134.                         :local o [find name="default-dhcp" ranges=192.168.88.10-192.168.88.254]
  135.                         :if ([:len $o] != 0) do={ remove $o }
  136.                 }
  137.                 :local o [/ip dhcp-client find comment="default configuration"]
  138.                 :if ([:len $o] != 0) do={ /ip dhcp-client remove $o }
  139.         /ip dns {
  140.                 set allow-remote-requests=no
  141.                 :local o [static find name=router address=192.168.88.1]
  142.                 :if ([:len $o] != 0) do={ static remove $o }
  143.         }
  144.         /ip address {
  145.                 :local o [find comment="default configuration"]
  146.                 :if ([:len $o] != 0) do={ remove $o }
  147.         }
  148. # remove switch
  149.         /interface set ether2-master-local name=ether2;
  150.         /interface ethernet set ether3-slave-local master-port=none;
  151.         /interface set ether3-slave-local name=ether3;
  152.         /interface ethernet set ether4-slave-local master-port=none;
  153.         /interface set ether4-slave-local name=ether4;
  154.         /interface ethernet set ether5-slave-local master-port=none;
  155.         /interface set ether5-slave-local name=ether5;
  156.         /interface bridge port remove [find bridge="bridge-local"]
  157.         /interface bridge remove [find name="bridge-local"]
  158.         /interface set [find name~"wlan1"] name=wlan1
  159.         /interface wireless reset-configuration wlan1
  160. }
複製代碼

TOP

角色

Rank: 2
3#
發表於 2014-9-9 01:41 | 只看該作者
本帖最後由 角色 於 2014-9-9 01:42 編輯

其他关于default configuration，可以参考下面网页
http://wiki.mikrotik.com/wiki/Manual:Default_Configurations

TOP

返回列表